mirror of
https://github.com/ash-project/ash.git
synced 2024-09-20 21:43:02 +12:00
f6f5d194bf
feat: validatiosn in actions feat: query arguments feat: add `Ash.Query.for_read/3` feat: return changeset with API errors feat: add case insensitive string `CiString`/`:ci_string` feat: support `context/1` and `arg/1` in filter templates feat: support targeting notifications with the `for` option feat: add `ago/2` query function feat: add basic arithmetic operators (+, *, -, /) feat: `sensitive?` option for attributes feat: `sensitive?` option for arguments feat: `private` arguments, which can’t be set using `for_<action>` feat: add `prevent_change` which will erase changes just before the changeset is committed feat: add `match?` validation that supports a custom error message feat: add `interval` type to support `ago/2` function feat: add `url_encoded_binary` type feat: add `function` type improvement: `changing?` is now a validation improvement: add `Transformer.get_persisted/3` improvement: add `api` field to `Notification` improvement: standardize errors, add `to_error_class` improvement: use `Comp` everywhere Improvement: use action on changeset if set by `for_<action_type>` improvement: `action_failed?` field on change sets improvement: remove ability for data layers to add operators (for now at least) Improvement: Changeset.apply_attributes/2 now returns an error tuple Improvement: add a bunch of new/informative errors improvement: runtime filter now uses left join logic (a naive implementation of it) improvement: support more filter templates in resources Improvement: basic/naive type system for operators/functions Fix: properly expand module aliases for options w/o compile time dependency chore(engine): track changeset changes for the request with `manage_changeset?: true`
383 lines
11 KiB
Elixir
383 lines
11 KiB
Elixir
defmodule Ash.Actions.PaginationTest do
|
|
use ExUnit.Case, async: true
|
|
|
|
require Ash.Query
|
|
|
|
defmodule User do
|
|
@moduledoc false
|
|
use Ash.Resource, data_layer: Ash.DataLayer.Ets
|
|
|
|
ets do
|
|
private?(true)
|
|
end
|
|
|
|
actions do
|
|
read :offset do
|
|
pagination offset?: true, countable: true
|
|
end
|
|
|
|
read :optional_offset do
|
|
pagination offset?: true, countable: true, required?: false
|
|
end
|
|
|
|
read :offset_countable_by_default do
|
|
pagination offset?: true, countable: :by_default, required?: false
|
|
end
|
|
|
|
read :required_offset_with_default do
|
|
pagination offset?: true, countable: true, required?: false, default_limit: 25
|
|
end
|
|
|
|
read :keyset do
|
|
pagination keyset?: true, countable: true
|
|
end
|
|
|
|
read :optional_keyset do
|
|
pagination keyset?: true, countable: true, required?: false
|
|
end
|
|
|
|
read :keyset_countable_by_default do
|
|
pagination keyset?: true, countable: :by_default, required?: false
|
|
end
|
|
|
|
read :required_keyset_with_default do
|
|
pagination keyset?: true, countable: true, required?: false, default_limit: 25
|
|
end
|
|
|
|
read :both_required do
|
|
primary? true
|
|
pagination keyset?: true, offset?: true, countable: true
|
|
end
|
|
|
|
read :both_optional do
|
|
pagination keyset?: true, offset?: true, countable: true, default_limit: 25
|
|
end
|
|
|
|
create :default
|
|
update :default
|
|
end
|
|
|
|
attributes do
|
|
uuid_primary_key :id
|
|
attribute :name, :string
|
|
end
|
|
end
|
|
|
|
defmodule Api do
|
|
use Ash.Api
|
|
|
|
resources do
|
|
resource User
|
|
end
|
|
end
|
|
|
|
test "pagination is required by default" do
|
|
assert_raise Ash.Error.Invalid, ~r/Pagination is required/, fn ->
|
|
Api.read!(User, page: false)
|
|
end
|
|
end
|
|
|
|
test "a default limit allows not specifying page parameters" do
|
|
assert_raise Ash.Error.Invalid, ~r/Limit is required/, fn ->
|
|
Api.read!(User, page: [offset: 1])
|
|
end
|
|
|
|
Api.read!(User, action: :required_offset_with_default)
|
|
end
|
|
|
|
describe "offset pagination" do
|
|
setup do
|
|
for i <- 0..9 do
|
|
Api.create!(Ash.Changeset.new(User, %{name: "#{i}"}))
|
|
end
|
|
|
|
:ok
|
|
end
|
|
|
|
test "can be limited" do
|
|
assert Enum.count(Api.read!(User, action: :optional_offset, page: false)) == 10
|
|
assert Enum.count(Api.read!(User, action: :optional_offset, page: [limit: 5]).results) == 5
|
|
end
|
|
|
|
test "can be offset" do
|
|
assert Enum.count(Api.read!(User, action: :optional_offset, page: false)) == 10
|
|
|
|
assert Enum.count(
|
|
Api.read!(User, action: :optional_offset, page: [offset: 5, limit: 5]).results
|
|
) == 5
|
|
end
|
|
|
|
test "can include a full count" do
|
|
assert Api.read!(User, action: :optional_offset, page: [limit: 1, count: true]).count == 10
|
|
end
|
|
|
|
test "can default to including a count" do
|
|
assert Api.read!(User, action: :offset_countable_by_default, page: [limit: 1]).count == 10
|
|
end
|
|
|
|
test "count is not included by default otherwise" do
|
|
assert is_nil(Api.read!(User, action: :optional_offset, page: [limit: 1]).count)
|
|
end
|
|
|
|
test "`count: false` prevents the count from occurring even if it is on `by_default`" do
|
|
assert is_nil(
|
|
Api.read!(User,
|
|
action: :offset_countable_by_default,
|
|
page: [limit: 1, count: false]
|
|
).count
|
|
)
|
|
end
|
|
|
|
test "pagination works with a sort applied" do
|
|
names =
|
|
User
|
|
|> Ash.Query.sort(:name)
|
|
|> Api.read!(page: [offset: 5, limit: 5])
|
|
|> Map.get(:results)
|
|
|> Enum.map(& &1.name)
|
|
|
|
assert names == ["5", "6", "7", "8", "9"]
|
|
end
|
|
|
|
test "pagination works with a reversed sort applied" do
|
|
names =
|
|
User
|
|
|> Ash.Query.sort(name: :desc)
|
|
|> Api.read!(page: [offset: 5, limit: 5])
|
|
|> Map.get(:results)
|
|
|> Enum.map(& &1.name)
|
|
|
|
assert names == ["4", "3", "2", "1", "0"]
|
|
end
|
|
|
|
test "pagination works with a filter" do
|
|
names =
|
|
User
|
|
|> Ash.Query.sort(name: :desc)
|
|
|> Ash.Query.filter(name in ["4", "3", "2", "1", "0"])
|
|
|> Api.read!(page: [offset: 1, limit: 5])
|
|
|> Map.get(:results)
|
|
|> Enum.map(& &1.name)
|
|
|
|
assert names == ["3", "2", "1", "0"]
|
|
end
|
|
|
|
test "the next page can be fetched" do
|
|
assert %{results: [%{name: "3"}]} =
|
|
page =
|
|
User
|
|
|> Ash.Query.sort(name: :desc)
|
|
|> Ash.Query.filter(name in ["4", "3", "2", "1", "0"])
|
|
|> Api.read!(page: [offset: 1, limit: 1])
|
|
|
|
assert %{results: [%{name: "2"}]} = Api.page!(page, :next)
|
|
end
|
|
|
|
test "the previous page can be fetched" do
|
|
assert %{results: [%{name: "3"}]} =
|
|
page =
|
|
User
|
|
|> Ash.Query.sort(name: :desc)
|
|
|> Ash.Query.filter(name in ["4", "3", "2", "1", "0"])
|
|
|> Api.read!(page: [offset: 1, limit: 1])
|
|
|
|
assert %{results: [%{name: "4"}]} = Api.page!(page, :prev)
|
|
end
|
|
|
|
test "the first page can be fetched" do
|
|
assert %{results: [%{name: "2"}]} =
|
|
page =
|
|
User
|
|
|> Ash.Query.sort(name: :desc)
|
|
|> Ash.Query.filter(name in ["4", "3", "2", "1", "0"])
|
|
|> Api.read!(page: [offset: 2, limit: 1])
|
|
|
|
assert %{results: [%{name: "4"}]} = Api.page!(page, :first)
|
|
end
|
|
|
|
test "the last page can be fetched if the count was requested" do
|
|
assert %{results: [%{name: "3"}]} =
|
|
page =
|
|
User
|
|
|> Ash.Query.sort(name: :desc)
|
|
|> Ash.Query.filter(name in ["4", "3", "2", "1", "0"])
|
|
|> Api.read!(page: [offset: 1, limit: 1, count: true])
|
|
|
|
assert %{results: [%{name: "0"}]} = Api.page!(page, :last)
|
|
end
|
|
end
|
|
|
|
describe "keyset pagination" do
|
|
setup do
|
|
for i <- 0..9 do
|
|
Api.create!(Ash.Changeset.new(User, %{name: "#{i}"}))
|
|
end
|
|
|
|
:ok
|
|
end
|
|
|
|
test "can be limited" do
|
|
assert Enum.count(Api.read!(User, action: :optional_keyset, page: false)) == 10
|
|
assert Enum.count(Api.read!(User, action: :optional_keyset, page: [limit: 5]).results) == 5
|
|
end
|
|
|
|
test "can include a full count" do
|
|
assert Api.read!(User, action: :optional_keyset, page: [limit: 1, count: true]).count == 10
|
|
end
|
|
|
|
test "can default to including a count" do
|
|
assert Api.read!(User, action: :keyset_countable_by_default, page: [limit: 1]).count == 10
|
|
end
|
|
|
|
test "count is not included by default otherwise" do
|
|
assert is_nil(Api.read!(User, action: :optional_keyset, page: [limit: 1]).count)
|
|
end
|
|
|
|
test "`count: false` prevents the count from occurring even if it is on `by_default`" do
|
|
assert is_nil(
|
|
Api.read!(User,
|
|
action: :keyset_countable_by_default,
|
|
page: [limit: 1, count: false]
|
|
).count
|
|
)
|
|
end
|
|
|
|
test "can ask for records after a specific keyset" do
|
|
%{results: [%{id: id, __metadata__: %{keyset: keyset}}]} =
|
|
Api.read!(User, action: :keyset, page: [limit: 1])
|
|
|
|
%{results: [%{id: next_id}]} =
|
|
Api.read!(User, action: :keyset, page: [limit: 1, after: keyset])
|
|
|
|
refute id == next_id
|
|
end
|
|
|
|
test "can ask for records before a specific keyset" do
|
|
%{results: [%{id: id, __metadata__: %{keyset: keyset}}]} =
|
|
Api.read!(User, action: :keyset, page: [limit: 1])
|
|
|
|
%{results: [%{id: next_id, __metadata__: %{keyset: keyset2}}]} =
|
|
Api.read!(User, action: :keyset, page: [limit: 1, after: keyset])
|
|
|
|
refute id == next_id
|
|
|
|
%{results: [%{id: before_id}]} =
|
|
Api.read!(User, action: :keyset, page: [limit: 1, before: keyset2])
|
|
|
|
assert id == before_id
|
|
end
|
|
|
|
test "pagination works with a sort applied" do
|
|
page =
|
|
User
|
|
|> Ash.Query.filter(name == "4")
|
|
|> Ash.Query.sort(:name)
|
|
|> Api.read!(page: [limit: 1])
|
|
|
|
keyset = Enum.at(page.results, 0).__metadata__.keyset
|
|
|
|
names =
|
|
User
|
|
|> Ash.Query.sort(:name)
|
|
|> Api.read!(page: [after: keyset, limit: 5])
|
|
|> Map.get(:results)
|
|
|> Enum.map(& &1.name)
|
|
|
|
assert names == ["5", "6", "7", "8", "9"]
|
|
end
|
|
|
|
test "pagination works with a reversed sort applied" do
|
|
page =
|
|
User
|
|
|> Ash.Query.filter(name == "5")
|
|
|> Ash.Query.sort(name: :desc)
|
|
|> Api.read!(page: [limit: 1])
|
|
|
|
keyset = Enum.at(page.results, 0).__metadata__.keyset
|
|
|
|
names =
|
|
User
|
|
|> Ash.Query.sort(name: :desc)
|
|
|> Api.read!(page: [after: keyset, limit: 5])
|
|
|> Map.get(:results)
|
|
|> Enum.map(& &1.name)
|
|
|
|
assert names == ["4", "3", "2", "1", "0"]
|
|
end
|
|
|
|
test "pagination works with a filter" do
|
|
page =
|
|
User
|
|
|> Ash.Query.filter(name == "5")
|
|
|> Ash.Query.sort(name: :desc)
|
|
|> Api.read!(page: [limit: 1])
|
|
|
|
keyset = Enum.at(page.results, 0).__metadata__.keyset
|
|
|
|
names =
|
|
User
|
|
|> Ash.Query.sort(name: :desc)
|
|
|> Ash.Query.filter(name != "4")
|
|
|> Api.read!(page: [after: keyset, limit: 5])
|
|
|> Map.get(:results)
|
|
|> Enum.map(& &1.name)
|
|
|
|
assert names == ["3", "2", "1", "0"]
|
|
end
|
|
|
|
test "the next page can be fetched" do
|
|
assert %{results: [%{name: "4"}]} =
|
|
page =
|
|
User
|
|
|> Ash.Query.sort(name: :desc)
|
|
|> Ash.Query.filter(name in ["4", "3", "2", "1", "0"])
|
|
|> Api.read!(page: [limit: 1])
|
|
|
|
assert %{results: [%{name: "3"}]} = Api.page!(page, :next)
|
|
end
|
|
|
|
test "the previous page can be fetched" do
|
|
assert %{results: [%{name: "4"}]} =
|
|
page =
|
|
User
|
|
|> Ash.Query.sort(name: :desc)
|
|
|> Ash.Query.filter(name in ["4", "3", "2", "1", "0"])
|
|
|> Api.read!(page: [limit: 1])
|
|
|
|
assert %{results: [%{name: "3"}]} = page = Api.page!(page, :next)
|
|
assert %{results: [%{name: "4"}]} = Api.page!(page, :prev)
|
|
end
|
|
|
|
test "the first page can be fetched" do
|
|
assert %{results: [%{name: "4"}]} =
|
|
page =
|
|
User
|
|
|> Ash.Query.sort(name: :desc)
|
|
|> Ash.Query.filter(name in ["4", "3", "2", "1", "0"])
|
|
|> Api.read!(page: [limit: 1])
|
|
|
|
assert %{results: [%{name: "3"}]} = page = Api.page!(page, :next)
|
|
assert %{results: [%{name: "4"}]} = Api.page!(page, :first)
|
|
end
|
|
end
|
|
|
|
describe "when both are supported" do
|
|
setup do
|
|
for i <- 0..9 do
|
|
Api.create!(Ash.Changeset.new(User, %{name: "#{i}"}))
|
|
end
|
|
|
|
:ok
|
|
end
|
|
|
|
test "it defaults to offset pagination" do
|
|
assert %Ash.Page.Offset{} = Api.read!(User, action: :both_optional, page: [limit: 10])
|
|
end
|
|
|
|
test "it adds a keyset to the records, even though it returns an offset page" do
|
|
for result <- Api.read!(User, action: :both_optional, page: [limit: 10]).results do
|
|
refute is_nil(result.__metadata__.keyset)
|
|
end
|
|
end
|
|
end
|
|
end
|