mirror of
https://github.com/ash-project/ash.git
synced 2024-09-20 13:33:20 +12:00
5967ed3a48
* improvement!: use `%Ash.NotSelected{}` for unselected values * improvement!: default `require_atomic?` to `true` * improvement!: raise errors on unknown generic action arguments * improvement!: default bulk strategy to `:atomic` * improvement!: warnings on `require_atomic?` `true` actions improvement!: revise `Ash.NotSelected` to `Ash.NotLoaded` improvement!: errors on unknown action inputs across the board * doc: clarify wording in notifiers.md closes #889 * improvement!: default `api.authorization.authorize` to `:by_default` * improvement!: require the api when constructing changesets this commit also fixes some work from prior commits around the default value for the `authorize` option * improvement!: code_interface.define_for -> code_interface.api `code_interface.define_for` is now `code_interface.api`. Additionally, it is set automatically if the `api` option is specified on `use Ash.Resource`. * improvement!: remove registries * improvement!: pubsub notifier default to `previous_values?: false` improvement!: requires_original_data? callback defaults to false * improvement!: rename Ash.Calculation -> Ash.Resource.Calculation improvement!: improve `Ash.Query.Calculation.new` signature improvement!: anonymous function calculations now take lists and return lists improvement!: make callback contexts into structs improvement!: pass context to builtin lifecycle hook changes improvement!: calculation arguments are now in the `arguments` key of the context * chore: fix build * improvement!: remove `aggregates` and `calculations` from `Filter.parse` and `Filter.parse_input` * improvement: update spark to 2.0 * improvement!: make picosat_elixir optional with `simple_sat` * improvement!: rename api to domain * docs: add more info to upgrading guide * docs: tweak docs formatting * improvement!: remove `Ash.Changeset.new!` * docs: update docs for `Ash.Changeset.new/1` * improvement!: deprecate `private?: false` in favor of `public?: true` * doc: add upgrade guide for private -> public * improvement: update reactor to 3.0 * improvement!: default `default_accept` is now `[]` * improvement!: `Ash.CiString.new/1` returns `nil` on `nil` input * improvement!(Ash.Reactor): Improve integration with Ash 3.0 changes. * improvement!: clean up and reorganize `Ash` functions this is in preparation of deprecating the functions that are defined on the api improvement!: remove context-based functionality * chore: update docs references from `Ash.Domain` to `Ash` * chore: fix bad merge * chore: fix context access in atomic changes * improvement!: Deprecate calling functions on (domain) api in favor of `Ash` * improvement!: add `attribute_public?` and update `attribute_writable?` behavior * improvement!: update atomic behaviors, default to invalid * chore: update downcase docs * improvement!: changeset.filters -> changeset.filter * improvement!: remove deprecated functions * improvement!: remove and simplify `Ash.Filter.TemplateHelpers` * improvement: import Ash.Expr in modules where it is used improvement: require Ash.QUery in modules where it makes sense * fix!: keyword lists are no longer special cased in ash expressions * improvement: add structs for more context implementations * chore: small tweaks, finish `:all` -> `:*` conversion * chore: update DSL docs for multitenancy.global? * improvement: ensure selects are applied on destroys chore: remove TODOs * chore: some docs changes * improvement!: introduce strict mode to calculations * chore: update tests * improvement: support custom expressions * docs: document custom expressions * chore: fix and test custom expressions and function fragments docs: update relevant docs w/ the changes * improvement!: reverse order of before action & before transaction hooks * improvement!: default read actions are now paginatable * improvement!: require explicit accept lists in default actions * chore: update docs * improvement!: remove Ash.Flow and Ash.Engine * chore: unlock unused deps * chore: don't use unused variable * chore: include ash flow change in upgrade guide * improvement!: standardize various exception keys and names * improvement!: use `Splode` for errors * improvement: update upgrade guide to include Splode * feat: code interface on the domain * improvement: only require primary key if resource has actions or fields improvement: only build schema if resource has actions or fields improvement: verify primary key in its own verifier * improvement: add `resource/1` builtin check * improvement!: move simple_notifiers to an option instead of a DSL builder improvement!: update spark for better autocomplete, configure autocomplete for key functions docs: replace `an domain` with `a domain` * improvement: better code interface documentation * fix: set tenant on query so that root calles to Api.aggreagte work as expected (#929) * chore: fixes from previous improvements * chore: update splode * chore: update splode * improvement!: swap position of sort order and arguments in calculation sorting * improvement!: add `include_nil?` aggregate option, and default it to `false` * improvement: support notifiers within actions * improvement: support specifying multiple filters * improvement: add `sortable?` flags to all fields improvement: support multiple filters on relationships * improvement: support sensitive? on calculations and arguments * improvement: validate resources in inputs to code interface * chore: don't require explicit accept lists when using `default_accept :*` * chore: update spark * chore: update public attribute handling per 3.0 * improvement: update reactor and tests * chore: better error message * chore: fix rebase issue * chore: handle merge issues improvement: don't require domain on relationships if destination has domain * improvement!: errors on unknown inputs for calculations * improvement: always choose to cast atomic * improvement: support casting some embeds atomically * improvement: various 3.0 updates, documented in upgrade.md * chore: Add failing tests for loads with with explicit domains. (#948) Co-authored-by: James Harton <james@harton.nz> * improvement: ensure non-static dynamic domains works * improvement: add Ash.ToTenant protocol * chore: add docs for no ToTenant option * fix: properly construct new query in `build/3` * chore: update simple_sat dependency * chore: don't reselect when missing primary keys * chore: remove IO.inspect * chore: update spark * chore: update spark * improvement: use `Keyword.put_new` in `Ash.Context.to_opts` (#953) * improvement: support bulk and atomic operations in code interfaces --------- Co-authored-by: James Harton <james@harton.nz> Co-authored-by: WIGGLES <55168935+WIGGLES-dev@users.noreply.github.com> Co-authored-by: Dmitry Maganov <vonagam@gmail.com>
578 lines
14 KiB
Elixir
578 lines
14 KiB
Elixir
defmodule Ash.Test.Changeset.EmbeddedResourceTest do
|
|
@moduledoc false
|
|
use ExUnit.Case, async: true
|
|
|
|
alias Ash.Changeset
|
|
|
|
require Ash.Query
|
|
|
|
defmodule Increasing do
|
|
use Ash.Resource.Validation
|
|
|
|
def init(opts), do: {:ok, opts}
|
|
|
|
def validate(changeset, opts, _) do
|
|
field = Keyword.get(opts, :field)
|
|
|
|
if Changeset.changing_attribute?(changeset, field) do
|
|
if Map.get(changeset.data, field) >=
|
|
Changeset.get_attribute(changeset, field) do
|
|
{:error, message: "must be increasing", field: field}
|
|
else
|
|
:ok
|
|
end
|
|
else
|
|
:ok
|
|
end
|
|
end
|
|
end
|
|
|
|
defmodule DestroyMe do
|
|
use Ash.Resource.Validation
|
|
|
|
def init(opts), do: {:ok, opts}
|
|
|
|
def validate(changeset, _opts, _) do
|
|
if Changeset.get_attribute(changeset, :first_name) == "destroy" &&
|
|
Changeset.get_attribute(changeset, :last_name) == "me" do
|
|
:ok
|
|
else
|
|
{:error, "must be named \"destroy me\" to remove a profile"}
|
|
end
|
|
end
|
|
end
|
|
|
|
defmodule ProfileWithId do
|
|
use Ash.Resource, data_layer: :embedded
|
|
|
|
attributes do
|
|
uuid_primary_key :id, writable?: true
|
|
|
|
attribute :first_name, :string do
|
|
public?(true)
|
|
end
|
|
|
|
attribute :last_name, :string do
|
|
public?(true)
|
|
end
|
|
|
|
attribute :counter, :integer, default: 0, allow_nil?: false, public?: true
|
|
end
|
|
|
|
validations do
|
|
validate present([:first_name, :last_name])
|
|
validate {Increasing, field: :counter}, on: :update
|
|
validate {DestroyMe, []}, on: :destroy
|
|
end
|
|
|
|
calculations do
|
|
calculate :full_name, :string, concat([:first_name, :last_name], " ") do
|
|
public? true
|
|
end
|
|
end
|
|
end
|
|
|
|
defmodule Profile do
|
|
use Ash.Resource, data_layer: :embedded
|
|
|
|
attributes do
|
|
attribute :first_name, :string do
|
|
public?(true)
|
|
end
|
|
|
|
attribute :last_name, :string do
|
|
public?(true)
|
|
end
|
|
|
|
attribute :counter, :integer, default: 0, allow_nil?: false, public?: true
|
|
end
|
|
|
|
validations do
|
|
validate present([:first_name, :last_name])
|
|
validate {Increasing, field: :counter}, on: :update
|
|
validate {DestroyMe, []}, on: :destroy
|
|
end
|
|
|
|
calculations do
|
|
calculate :full_name, :string, concat([:first_name, :last_name], " ") do
|
|
public? true
|
|
end
|
|
end
|
|
end
|
|
|
|
defmodule Tag do
|
|
use Ash.Resource, data_layer: :embedded
|
|
|
|
attributes do
|
|
attribute :name, :string do
|
|
public?(true)
|
|
end
|
|
|
|
attribute :score, :integer do
|
|
public?(true)
|
|
end
|
|
end
|
|
|
|
validations do
|
|
# You can't remove a tag unless you first set its score to 0
|
|
validate absent(:score), on: :destroy
|
|
validate {Increasing, field: :score}, on: :update
|
|
validate present(:score), on: :create
|
|
end
|
|
end
|
|
|
|
defmodule TagWithNoNils do
|
|
use Ash.Resource, data_layer: :embedded, embed_nil_values?: false
|
|
|
|
attributes do
|
|
attribute :name, :string do
|
|
public?(true)
|
|
end
|
|
|
|
attribute :score, :integer do
|
|
public?(true)
|
|
end
|
|
end
|
|
|
|
validations do
|
|
# You can't remove a tag unless you first set its score to 0
|
|
validate absent(:score), on: :destroy
|
|
validate {Increasing, field: :score}, on: :update
|
|
validate present(:score), on: :create
|
|
end
|
|
end
|
|
|
|
defmodule TagWithId do
|
|
use Ash.Resource, data_layer: :embedded
|
|
|
|
attributes do
|
|
uuid_primary_key :id, writable?: true
|
|
|
|
attribute :type, :string do
|
|
public?(true)
|
|
end
|
|
|
|
attribute :name, :string do
|
|
public?(true)
|
|
end
|
|
|
|
attribute :score, :integer do
|
|
public?(true)
|
|
end
|
|
end
|
|
|
|
validations do
|
|
# You can't remove a tag unless you first set its score to 0
|
|
validate absent(:score), on: :destroy
|
|
validate {Increasing, field: :score}, on: :update
|
|
validate present(:score), on: :create
|
|
end
|
|
end
|
|
|
|
defmodule UnionTagWithId do
|
|
use Ash.Type.NewType,
|
|
subtype_of: :union,
|
|
constraints: [
|
|
types: [
|
|
tag: [
|
|
type: TagWithId,
|
|
tag: :type,
|
|
tag_value: :tag_with_id
|
|
]
|
|
]
|
|
]
|
|
end
|
|
|
|
defmodule Author do
|
|
use Ash.Resource,
|
|
domain: Ash.Test.Changeset.EmbeddedResourceTest.Domain,
|
|
data_layer: Ash.DataLayer.Ets
|
|
|
|
ets do
|
|
private?(true)
|
|
end
|
|
|
|
actions do
|
|
default_accept :*
|
|
create :create
|
|
update :update
|
|
end
|
|
|
|
attributes do
|
|
uuid_primary_key :id, writable?: true
|
|
|
|
attribute :profile, Profile,
|
|
constraints: [
|
|
load: [:full_name]
|
|
],
|
|
public?: true
|
|
|
|
attribute :profile_with_id, ProfileWithId,
|
|
constraints: [
|
|
load: [:full_name]
|
|
],
|
|
public?: true
|
|
|
|
attribute :tags, {:array, Tag} do
|
|
public?(true)
|
|
end
|
|
|
|
attribute :tags_max_length, {:array, Tag} do
|
|
public?(true)
|
|
constraints max_length: 2, min_length: 1
|
|
end
|
|
|
|
attribute :tags_with_id, {:array, TagWithId} do
|
|
public?(true)
|
|
end
|
|
|
|
attribute :union_tags_with_id, {:array, UnionTagWithId} do
|
|
public?(true)
|
|
end
|
|
end
|
|
end
|
|
|
|
defmodule Domain do
|
|
@moduledoc false
|
|
use Ash.Domain
|
|
|
|
resources do
|
|
resource Author
|
|
end
|
|
end
|
|
|
|
test "embedded resources can be created" do
|
|
assert %{profile: %Profile{}, tags: [%Tag{name: "trainer"}, %Tag{name: "human"}]} =
|
|
Changeset.for_create(
|
|
Author,
|
|
:create,
|
|
%{
|
|
profile: %{
|
|
first_name: "ash",
|
|
last_name: "ketchum"
|
|
},
|
|
tags: [
|
|
%{name: "trainer", score: 10},
|
|
%{name: "human", score: 100}
|
|
]
|
|
}
|
|
)
|
|
|> Ash.create!()
|
|
end
|
|
|
|
test "embed_nil_values?: false causes nil values not to be dumped" do
|
|
value = %TagWithNoNils{name: "foo", score: nil}
|
|
assert {:ok, dumped} = Ash.Type.dump_to_embedded(TagWithNoNils, value, [])
|
|
assert Map.keys(dumped) == [:name]
|
|
end
|
|
|
|
test "embedded resources can be constrained with min/max length" do
|
|
assert_raise Ash.Error.Invalid, ~r/must have 2 or fewer items/, fn ->
|
|
Changeset.for_create(
|
|
Author,
|
|
:create,
|
|
%{
|
|
profile: %{
|
|
first_name: "ash",
|
|
last_name: "ketchum"
|
|
},
|
|
tags_max_length: [
|
|
%{name: "trainer", score: 10},
|
|
%{name: "human", score: 100},
|
|
%{name: "gym_leader", score: 150}
|
|
]
|
|
}
|
|
)
|
|
|> Ash.create!()
|
|
end
|
|
|
|
assert_raise Ash.Error.Invalid, ~r/must have 1 or more items/, fn ->
|
|
Changeset.for_create(
|
|
Author,
|
|
:create,
|
|
%{
|
|
profile: %{
|
|
first_name: "ash",
|
|
last_name: "ketchum"
|
|
},
|
|
tags_max_length: []
|
|
}
|
|
)
|
|
|> Ash.create!()
|
|
end
|
|
end
|
|
|
|
test "embedded resources support calculations" do
|
|
assert %{profile: %Profile{full_name: "ash ketchum"}} =
|
|
Changeset.for_create(
|
|
Author,
|
|
:create,
|
|
%{
|
|
profile: %{
|
|
first_name: "ash",
|
|
last_name: "ketchum"
|
|
}
|
|
}
|
|
)
|
|
|> Ash.create!()
|
|
end
|
|
|
|
test "embedded resources run validations on create" do
|
|
msg =
|
|
~r/Invalid value provided for last_name: exactly 2 of first_name,last_name must be present/
|
|
|
|
assert_raise Ash.Error.Invalid,
|
|
msg,
|
|
fn ->
|
|
Author
|
|
|> Changeset.for_create(
|
|
:create,
|
|
%{
|
|
profile: %{
|
|
first_name: "ash"
|
|
}
|
|
}
|
|
)
|
|
|> Ash.create!()
|
|
end
|
|
end
|
|
|
|
test "embedded resources run validations on update" do
|
|
assert author =
|
|
Changeset.for_create(
|
|
Author,
|
|
:create,
|
|
%{
|
|
profile: %{
|
|
first_name: "ash",
|
|
last_name: "ketchum"
|
|
}
|
|
}
|
|
)
|
|
|> Ash.create!()
|
|
|
|
input = %{counter: author.profile.counter - 1}
|
|
|
|
assert_raise Ash.Error.Invalid,
|
|
~r/Invalid value provided for counter: must be increasing/,
|
|
fn ->
|
|
Changeset.for_update(
|
|
author,
|
|
:update,
|
|
%{
|
|
profile: input
|
|
}
|
|
)
|
|
|> Ash.update!()
|
|
end
|
|
end
|
|
|
|
test "embedded resources run validations on destroy" do
|
|
assert author =
|
|
Changeset.for_create(
|
|
Author,
|
|
:create,
|
|
%{
|
|
profile: %{
|
|
first_name: "ash",
|
|
last_name: "ketchum"
|
|
}
|
|
}
|
|
)
|
|
|> Ash.create!()
|
|
|
|
assert_raise Ash.Error.Invalid, ~r/must be named "destroy me" to remove a profile/, fn ->
|
|
Changeset.for_update(
|
|
author,
|
|
:update,
|
|
%{profile: nil}
|
|
)
|
|
|> Ash.update!()
|
|
end
|
|
|
|
author =
|
|
Changeset.for_update(
|
|
author,
|
|
:update,
|
|
%{profile: %{first_name: "destroy", last_name: "me"}}
|
|
)
|
|
|> Ash.update!()
|
|
|
|
Changeset.for_update(
|
|
author,
|
|
:update,
|
|
%{profile: nil}
|
|
)
|
|
|> Ash.update!()
|
|
end
|
|
|
|
test "when a non-array embedded resource has a public primary key, changes are considered a destroy + create, not an update" do
|
|
assert author =
|
|
Changeset.for_create(
|
|
Author,
|
|
:create,
|
|
%{
|
|
profile_with_id: %{
|
|
first_name: "ash",
|
|
last_name: "ketchum"
|
|
}
|
|
}
|
|
)
|
|
|> Ash.create!()
|
|
|
|
assert_raise Ash.Error.Invalid, ~r/must be named "destroy me" to remove a profile/, fn ->
|
|
Changeset.for_update(
|
|
author,
|
|
:update,
|
|
%{profile_with_id: %{first_name: "foo", last_name: "bar"}}
|
|
)
|
|
|> Ash.update!()
|
|
end
|
|
|
|
author =
|
|
Changeset.for_update(
|
|
author,
|
|
:update,
|
|
%{
|
|
profile_with_id: %{
|
|
id: author.profile_with_id.id,
|
|
first_name: "destroy",
|
|
last_name: "me"
|
|
}
|
|
}
|
|
)
|
|
|> Ash.update!()
|
|
|
|
Changeset.for_update(
|
|
author,
|
|
:update,
|
|
%{profile_with_id: %{first_name: "foo", last_name: "bar"}}
|
|
)
|
|
|> Ash.update!()
|
|
end
|
|
|
|
test "a list of embeds without an id are destroyed and created each time" do
|
|
assert author =
|
|
Changeset.for_create(
|
|
Author,
|
|
:create,
|
|
%{
|
|
tags: [
|
|
%{name: "trainer", score: 10},
|
|
%{name: "human", score: 100}
|
|
]
|
|
}
|
|
)
|
|
|> Ash.create!()
|
|
|
|
assert_raise Ash.Error.Invalid,
|
|
~r/Invalid value provided for score: must be present/,
|
|
fn ->
|
|
Changeset.for_update(
|
|
author,
|
|
:update,
|
|
%{
|
|
tags: [
|
|
%{name: "pokemon"}
|
|
]
|
|
}
|
|
)
|
|
|> Ash.update!()
|
|
end
|
|
|
|
assert_raise Ash.Error.Invalid,
|
|
~r/Invalid value provided for score: must be absent/,
|
|
fn ->
|
|
Changeset.for_update(
|
|
author,
|
|
:update,
|
|
%{
|
|
tags: [
|
|
%{name: "pokemon", score: 1}
|
|
]
|
|
}
|
|
)
|
|
|> Ash.update!()
|
|
end
|
|
end
|
|
|
|
test "a list of embeds are updated where appropriate" do
|
|
assert %{tags_with_id: [tag]} =
|
|
author =
|
|
Changeset.for_create(
|
|
Author,
|
|
:create,
|
|
%{
|
|
tags_with_id: [
|
|
%{name: "trainer", score: 10}
|
|
]
|
|
}
|
|
)
|
|
|> Ash.create!()
|
|
|
|
exception =
|
|
assert_raise Ash.Error.Invalid,
|
|
~r/Invalid value provided for score: must be increasing/,
|
|
fn ->
|
|
Changeset.for_update(
|
|
author,
|
|
:update,
|
|
%{
|
|
tags_with_id: [
|
|
%{id: tag.id, score: 1}
|
|
]
|
|
}
|
|
)
|
|
|> Ash.update!()
|
|
end
|
|
|
|
assert Enum.at(exception.errors, 0).path == [:tags_with_id, 0]
|
|
|
|
applied_author =
|
|
Changeset.for_update(
|
|
author,
|
|
:update,
|
|
%{
|
|
tags_with_id: [
|
|
%{id: tag.id, score: 100}
|
|
]
|
|
}
|
|
)
|
|
|> Ash.update!()
|
|
|
|
# The ID of the Tag should not change
|
|
assert Enum.map(applied_author.tags_with_id, & &1.id) ==
|
|
Enum.map(author.tags_with_id, & &1.id)
|
|
end
|
|
|
|
test "a list of union embeds are updated where appropriate" do
|
|
assert %{union_tags_with_id: [%Ash.Union{value: tag}]} =
|
|
author =
|
|
Changeset.for_create(
|
|
Author,
|
|
:create,
|
|
%{
|
|
union_tags_with_id: [
|
|
%{name: "trainer", score: 10, type: "tag_with_id"}
|
|
]
|
|
}
|
|
)
|
|
|> Ash.create!()
|
|
|
|
applied_author =
|
|
Changeset.for_update(
|
|
author,
|
|
:update,
|
|
%{
|
|
union_tags_with_id: [
|
|
%{id: tag.id, score: 100, type: "tag_with_id"}
|
|
]
|
|
}
|
|
)
|
|
|> Ash.update!()
|
|
|
|
# The id of the Union Tag should not change
|
|
assert Enum.map(applied_author.union_tags_with_id, & &1.value.id) ==
|
|
Enum.map(author.union_tags_with_id, & &1.value.id)
|
|
end
|
|
end
|