mirror of
https://github.com/ash-project/ash.git
synced 2024-09-21 14:03:04 +12:00
5967ed3a48
* improvement!: use `%Ash.NotSelected{}` for unselected values * improvement!: default `require_atomic?` to `true` * improvement!: raise errors on unknown generic action arguments * improvement!: default bulk strategy to `:atomic` * improvement!: warnings on `require_atomic?` `true` actions improvement!: revise `Ash.NotSelected` to `Ash.NotLoaded` improvement!: errors on unknown action inputs across the board * doc: clarify wording in notifiers.md closes #889 * improvement!: default `api.authorization.authorize` to `:by_default` * improvement!: require the api when constructing changesets this commit also fixes some work from prior commits around the default value for the `authorize` option * improvement!: code_interface.define_for -> code_interface.api `code_interface.define_for` is now `code_interface.api`. Additionally, it is set automatically if the `api` option is specified on `use Ash.Resource`. * improvement!: remove registries * improvement!: pubsub notifier default to `previous_values?: false` improvement!: requires_original_data? callback defaults to false * improvement!: rename Ash.Calculation -> Ash.Resource.Calculation improvement!: improve `Ash.Query.Calculation.new` signature improvement!: anonymous function calculations now take lists and return lists improvement!: make callback contexts into structs improvement!: pass context to builtin lifecycle hook changes improvement!: calculation arguments are now in the `arguments` key of the context * chore: fix build * improvement!: remove `aggregates` and `calculations` from `Filter.parse` and `Filter.parse_input` * improvement: update spark to 2.0 * improvement!: make picosat_elixir optional with `simple_sat` * improvement!: rename api to domain * docs: add more info to upgrading guide * docs: tweak docs formatting * improvement!: remove `Ash.Changeset.new!` * docs: update docs for `Ash.Changeset.new/1` * improvement!: deprecate `private?: false` in favor of `public?: true` * doc: add upgrade guide for private -> public * improvement: update reactor to 3.0 * improvement!: default `default_accept` is now `[]` * improvement!: `Ash.CiString.new/1` returns `nil` on `nil` input * improvement!(Ash.Reactor): Improve integration with Ash 3.0 changes. * improvement!: clean up and reorganize `Ash` functions this is in preparation of deprecating the functions that are defined on the api improvement!: remove context-based functionality * chore: update docs references from `Ash.Domain` to `Ash` * chore: fix bad merge * chore: fix context access in atomic changes * improvement!: Deprecate calling functions on (domain) api in favor of `Ash` * improvement!: add `attribute_public?` and update `attribute_writable?` behavior * improvement!: update atomic behaviors, default to invalid * chore: update downcase docs * improvement!: changeset.filters -> changeset.filter * improvement!: remove deprecated functions * improvement!: remove and simplify `Ash.Filter.TemplateHelpers` * improvement: import Ash.Expr in modules where it is used improvement: require Ash.QUery in modules where it makes sense * fix!: keyword lists are no longer special cased in ash expressions * improvement: add structs for more context implementations * chore: small tweaks, finish `:all` -> `:*` conversion * chore: update DSL docs for multitenancy.global? * improvement: ensure selects are applied on destroys chore: remove TODOs * chore: some docs changes * improvement!: introduce strict mode to calculations * chore: update tests * improvement: support custom expressions * docs: document custom expressions * chore: fix and test custom expressions and function fragments docs: update relevant docs w/ the changes * improvement!: reverse order of before action & before transaction hooks * improvement!: default read actions are now paginatable * improvement!: require explicit accept lists in default actions * chore: update docs * improvement!: remove Ash.Flow and Ash.Engine * chore: unlock unused deps * chore: don't use unused variable * chore: include ash flow change in upgrade guide * improvement!: standardize various exception keys and names * improvement!: use `Splode` for errors * improvement: update upgrade guide to include Splode * feat: code interface on the domain * improvement: only require primary key if resource has actions or fields improvement: only build schema if resource has actions or fields improvement: verify primary key in its own verifier * improvement: add `resource/1` builtin check * improvement!: move simple_notifiers to an option instead of a DSL builder improvement!: update spark for better autocomplete, configure autocomplete for key functions docs: replace `an domain` with `a domain` * improvement: better code interface documentation * fix: set tenant on query so that root calles to Api.aggreagte work as expected (#929) * chore: fixes from previous improvements * chore: update splode * chore: update splode * improvement!: swap position of sort order and arguments in calculation sorting * improvement!: add `include_nil?` aggregate option, and default it to `false` * improvement: support notifiers within actions * improvement: support specifying multiple filters * improvement: add `sortable?` flags to all fields improvement: support multiple filters on relationships * improvement: support sensitive? on calculations and arguments * improvement: validate resources in inputs to code interface * chore: don't require explicit accept lists when using `default_accept :*` * chore: update spark * chore: update public attribute handling per 3.0 * improvement: update reactor and tests * chore: better error message * chore: fix rebase issue * chore: handle merge issues improvement: don't require domain on relationships if destination has domain * improvement!: errors on unknown inputs for calculations * improvement: always choose to cast atomic * improvement: support casting some embeds atomically * improvement: various 3.0 updates, documented in upgrade.md * chore: Add failing tests for loads with with explicit domains. (#948) Co-authored-by: James Harton <james@harton.nz> * improvement: ensure non-static dynamic domains works * improvement: add Ash.ToTenant protocol * chore: add docs for no ToTenant option * fix: properly construct new query in `build/3` * chore: update simple_sat dependency * chore: don't reselect when missing primary keys * chore: remove IO.inspect * chore: update spark * chore: update spark * improvement: use `Keyword.put_new` in `Ash.Context.to_opts` (#953) * improvement: support bulk and atomic operations in code interfaces --------- Co-authored-by: James Harton <james@harton.nz> Co-authored-by: WIGGLES <55168935+WIGGLES-dev@users.noreply.github.com> Co-authored-by: Dmitry Maganov <vonagam@gmail.com>
253 lines
7.7 KiB
Elixir
253 lines
7.7 KiB
Elixir
if Code.ensure_loaded?(Plug.Conn) do
|
|
defmodule Ash.PlugHelpers do
|
|
@moduledoc """
|
|
Helpers for working with the Plug connection.
|
|
"""
|
|
|
|
alias Plug.Conn
|
|
require Logger
|
|
|
|
defmacrop emit_assign_warning(type) do
|
|
quote do
|
|
Logger.warning(fn ->
|
|
{fun, arity} = __ENV__.function
|
|
file = Path.relative_to_cwd(__ENV__.file)
|
|
|
|
"""
|
|
Storing the #{unquote(type)} in conn assigns is deprecated.
|
|
#{file}:#{__ENV__.line}: #{inspect(__ENV__.module)}.#{fun}/#{arity}
|
|
"""
|
|
end)
|
|
end
|
|
end
|
|
|
|
@doc """
|
|
Sets the actor inside the Plug connection.
|
|
|
|
The actor is stored inside the [connection's private
|
|
fields](https://hexdocs.pm/plug/Plug.Conn.html#module-private-fields).
|
|
|
|
## Example
|
|
|
|
iex> actor = build_actor(%{email: "marty@1985.retro"})
|
|
...> conn = build_conn() |> set_actor(actor)
|
|
%Plug.Conn{private: %{ash: %{actor: %{email: "marty@1985.retro"}}}} = conn
|
|
|
|
"""
|
|
@spec set_actor(Conn.t(), Ash.Resource.record()) :: Conn.t()
|
|
def set_actor(conn, actor) do
|
|
ash_private =
|
|
conn.private
|
|
|> Map.get(:ash, %{})
|
|
|> Map.put(:actor, actor)
|
|
|
|
conn
|
|
|> Conn.put_private(:ash, ash_private)
|
|
end
|
|
|
|
@doc """
|
|
Retrieves the actor from the Plug connection.
|
|
|
|
The actor is stored inside the [connection's private
|
|
fields](https://hexdocs.pm/plug/Plug.Conn.html#module-private-fields).
|
|
|
|
## Deprecation warning
|
|
|
|
This function checks to see if the actor is already set in the `@actor`
|
|
assign, and if so will emit a deprecation warning.
|
|
|
|
This is to allow apps using the previous method a chance to update.
|
|
|
|
Rather than setting the actor in the assigns, please use the `set_actor/2`
|
|
method.
|
|
|
|
## Example
|
|
|
|
iex> actor = build_actor(%{email: "marty@1985.retro"})
|
|
...> conn = build_conn() |> put_private(:ash, %{actor: actor})
|
|
...> actor = get_actor(conn)
|
|
%{email: "marty@1985.retro"} = actor
|
|
|
|
iex> actor = build_actor(%{email: "marty@1985.retro"})
|
|
...> conn = build_conn() |> assign(:actor, actor)
|
|
...> actor = get_actor(conn)
|
|
%{email: "marty@1985.retro"} = actor
|
|
"""
|
|
@spec get_actor(Conn.t()) :: nil | Ash.Resource.record()
|
|
def get_actor(%{assigns: %{actor: actor}}) when not is_nil(actor) do
|
|
emit_assign_warning(:actor)
|
|
|
|
actor
|
|
end
|
|
|
|
def get_actor(%{private: %{ash: %{actor: actor}}}), do: actor
|
|
def get_actor(_), do: nil
|
|
|
|
@doc """
|
|
Updates the actor inside the Plug connection.
|
|
|
|
The actor is stored inside the [connection's private
|
|
fields](https://hexdocs.pm/plug/Plug.Conn.html#module-private-fields).
|
|
|
|
## Example
|
|
|
|
iex> actor = build_actor(%{email: "marty@1985.retro"})
|
|
...> conn = build_conn() |> put_private(:ash, %{actor: actor})
|
|
...> actor = get_actor(conn)
|
|
%{email: "marty@1985.retro"} = actor
|
|
...> conn = update_actor(conn, fn actor -> Map.put(actor, :name, "Marty Retro") end)
|
|
...> actor = get_actor(conn)
|
|
%{email: "marty@1985.retro", name: "Marty Retro"} = actor
|
|
...> conn = update_actor(conn, fn actor -> Map.delete(actor, :email) end)
|
|
...> actor = get_actor(conn)
|
|
%{name: "Marty Retro"} = actor
|
|
"""
|
|
@spec update_actor(Conn.t(), (nil | Ash.Resource.record() -> nil | Ash.Resource.record())) ::
|
|
Conn.t()
|
|
def update_actor(conn, callback) do
|
|
case get_actor(conn) do
|
|
nil ->
|
|
conn
|
|
|
|
actor ->
|
|
conn
|
|
|> set_actor(callback.(actor))
|
|
end
|
|
end
|
|
|
|
@doc """
|
|
Sets the tenant inside the Plug connection.
|
|
|
|
The tenant is stored inside the [connection's private
|
|
fields](https://hexdocs.pm/plug/Plug.Conn.html#module-private-fields).
|
|
|
|
## Example
|
|
|
|
iex> conn = build_conn() |> set_tenant("my-tenant")
|
|
%Plug.Conn{private: %{ash: %{tenant: "my-tenant}}} = conn
|
|
"""
|
|
@spec set_tenant(Conn.t(), Ash.ToTenant.t()) :: Conn.t()
|
|
def set_tenant(conn, tenant) do
|
|
ash_private =
|
|
conn.private
|
|
|> Map.get(:ash, %{})
|
|
|> Map.put(:tenant, tenant)
|
|
|
|
conn
|
|
|> Conn.put_private(:ash, ash_private)
|
|
end
|
|
|
|
@doc """
|
|
Retrieves the tenant from the Plug connection.
|
|
|
|
The tenant is stored inside the [connection's private
|
|
fields](https://hexdocs.pm/plug/Plug.Conn.html#module-private-fields).
|
|
|
|
## Deprecation warning
|
|
|
|
This function checks to see if the tenant is already set in the `@tenant`
|
|
assign, and if so will emit a deprecation warning.
|
|
|
|
This is to allow apps using the previous method a chance to update.
|
|
|
|
Rather than setting the tenant in the assigns, please use the `set_tenant/2`
|
|
method.
|
|
|
|
|
|
## Example
|
|
|
|
iex> conn = build_conn() |> put_private(:ash, %{tenant: "my-tenant"})
|
|
...> tenant = get_tenant(conn)
|
|
"my_tenant" = tenant
|
|
|
|
iex> conn = build_conn() |> assign(:tenant, "my-tenant")
|
|
...> tenant = get_tenant(conn)
|
|
"my_tenant" = tenant
|
|
"""
|
|
@spec get_tenant(Conn.t()) :: term()
|
|
def get_tenant(%{assigns: %{tenant: tenant}}) when not is_nil(tenant) do
|
|
emit_assign_warning(:tenant)
|
|
|
|
tenant
|
|
end
|
|
|
|
def get_tenant(%{private: %{ash: %{tenant: tenant}}}), do: tenant
|
|
def get_tenant(_), do: nil
|
|
|
|
@doc """
|
|
Sets the context inside the Plug connection.
|
|
|
|
Context can be used to store abitrary data about the user, connection, or
|
|
anything else you like that doesn't belong as part of the actor or tenant.
|
|
|
|
The context is stored inside the [connection's private
|
|
fields](https://hexdocs.pm/plug/Plug.Conn.html#module-private-fields).
|
|
|
|
## Example
|
|
|
|
iex> context = %{fraud_score: 0.427}
|
|
...> conn = build_conn() |> set_context(context)
|
|
%Plug.Conn{private: %{ash: %{context: %{fraud_score: 0.427}}}}
|
|
|
|
"""
|
|
@spec set_context(Conn.t(), map()) :: Conn.t()
|
|
def set_context(conn, context) do
|
|
ash_private =
|
|
conn.private
|
|
|> Map.get(:ash, %{})
|
|
|> Map.put(:context, context)
|
|
|
|
conn
|
|
|> Conn.put_private(:ash, ash_private)
|
|
end
|
|
|
|
@doc """
|
|
Retrieves the context from the Plug connection.
|
|
|
|
The context is stored inside the [connection's private
|
|
fields](https://hexdocs.pm/plug/Plug.Conn.html#module-private-fields).
|
|
|
|
## Example
|
|
|
|
iex> context = %{fraud_score: 0.427}
|
|
...> conn = build_conn() |> put_private(:ash, %{context: context})
|
|
...> context = get_context(conn)
|
|
%{fraud_score: 0.427}
|
|
"""
|
|
@spec get_context(Conn.t()) :: nil | map()
|
|
def get_context(%{private: %{ash: %{context: context}}}), do: context
|
|
def get_context(_), do: nil
|
|
|
|
@doc """
|
|
Updates the context inside the Plug connection.
|
|
|
|
The context is stored inside the [connection's private
|
|
fields](https://hexdocs.pm/plug/Plug.Conn.html#module-private-fields).
|
|
|
|
## Example
|
|
|
|
iex> context = %{species: "Fythetropozoat"}
|
|
...> conn = build_conn() |> put_private(:ash, %{context: context})
|
|
...> context = get_context(conn)
|
|
%{fraud_score: 0.427}
|
|
...> conn = update_context(conn, fn context -> Map.put(context, :location, "Barnard's Loop") end)
|
|
...> context = get_context(conn)
|
|
%{species: "Fythetropozoat", location: "Barnard's Loop"}
|
|
...> conn = update_context(conn, fn context -> Map.delete(context, :fraud_score) end)
|
|
...> context = get_context(conn)
|
|
%{location: "Barnard's Loop"}
|
|
"""
|
|
@spec update_context(Conn.t(), (nil | map() -> nil | map())) ::
|
|
Conn.t()
|
|
def update_context(conn, callback) do
|
|
case get_context(conn) do
|
|
nil ->
|
|
conn
|
|
|
|
context ->
|
|
conn
|
|
|> set_context(callback.(context))
|
|
end
|
|
end
|
|
end
|
|
end
|